***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 10, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD25N04V-AU     drain  gate  source
Lg     gate   g1   2.2n
Ld     drain  d1   100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.37
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=88.7  VTO=3.88  LEVEL=3  VMAX=1.2e5  ETA=0.006  gamma=1.7 )
Rd     d1    d2    7.0m TC=4.8m,10u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=44     TBV1=5.917e-4   TBV2=-2.3e-7  CJO=5.868e-10  M=1.135  VJ=9.298)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=9.067e-12  N=1.121  RS=0.04u  EG=1.160  TT=30n  ikf=7.565e+1)
Rdiode  d1  21    7.272e-3 TC=2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.510e-10
.MODEL     DGD    D(M=1.405  CJO=1.510e-10   VJ=7.306)
Rpar      b    d2   1Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    5.3861e-10
.ENDS
*$
